Jump to content
Rafadin

Macra Poradnik

Recommended Posts

Rafadin    1

Jeśli ktoś chciałby sobie ułatwić rozgrywkę macrami to tutaj mały poradnik:

Podstawowe funkcje

#showtooltip tu_możesz_wpisać_nazwę_umiejętności_do_wyświetlania(opcjonalne) Wielkość liter w macrach nie ma znaczenia
/target Wybiera cel.
/assist Wybiera cel celu.
/targetlasttarget Wraca do poprzedniego celu.
/startattack Zaczyna atakować w przypadku zgubienia targetu - melasi docenią.
/stopattack Przerywa atakowanie.
/cancelaura nazwa_aury(buff) Kończy działanie buffa.
/stopcasting Przerywa bieżące "czarowanie". Przyda się wszystkim, nie tylko casterom, a w szczególności osobom z wysokim
opóźnieniem(w grze xd) - w praktyce jest to zmniejszenie latency o połowę a tym samym zwiększenie dps, hps i tps :). Na pewno
zauważycie większą płynność w swojej rotacji.
/cast [warunki_do_spełnienia_opcjonalnie] - nawias kwadratowy! Używa umiejętność jaką tylko chcesz. W przypadku więcej niż jednego warunku w macro konieczne jest postawienie przecinka pomiędzy warunkami!
W warunkach do spełnienia możemy dodać:
-harm - zadziała tylko gdy celem jest wróg
-help - zadziała gdy celem jest kolega
-nodead - tylko żywe cele
-dead - tylko martwe cele
-combat - podczas walki
-nocombat - poza walką
-@mouesover lub target=mouseover - bez potrzeby targetowania użyje umiejętności tylko na celu "najechanym" kursorem/myszką
-target=nazwacelu/target=focus/target=player/@player - na kogo chcesz
-spec:1 lub spec:2 - użyje tylko w main lub offspecu
-stance:1/stance:2/stance:3 - tylko w określonym stance  - działa dla form druida, stance'ów warriora i podobno metamorfozy demonologa.
-flyable - tam gdzie można latać
-noflyable - gdzie nie można latać
-pet - tylko gdy przywołany jest twój zwierzak


/castsequence reset=długość_cd(w sekundach) nazwa_umiejętności,nazwa_umiejętności
Używa umiejętności jedna po drugiej. Resetuje się po wpisanym czasie lub po dwukrotnym użyciu. Najlepiej podać czas pierwszej
umiejętności w sekwencji.
/use nazwa_przedmiotu_lub_numer_porządkowy 
Używa wybrany przedmiot. Numery porządkowe tj:
1 - czapka(inżynier)
6 - pas(inżynier)
8 - buty(inżynier)
10 - rękawice(inżynier)
13 - trinket 1
14 - trinket 2
15 - peleryna(inżynier)

Interfejs

/run UIErrorsFrame:Hide() Usuwa czerwone powiadomienia na środku ekranu(error). Można dodać do swojej rotacji.
/script SetCVar ("cameraDistancemax" ,50) /console CameraDistanceMaxFactor 5 Wystarczy wkleić w czat - teraz możesz oddalić kamerę dalej. Przydatne np do walki z Heiganem(taniec). Użyć raz na postać.
/run local f = CreateFrame("frame", nil, UIParent); f:SetScript("OnUpdate", CombatLogClearEntries) Reset zaciętych addonów np gdy Recount nie podlicza
/reload wczyta interfejs od nowa

Przykłady macr

Kilka przykładów dla objaśnienia. Każde z macr poniżej wykorzystuje inną mechanikę, którą można bez problemu zastosować do każdej klasy -
wystarczy pozmieniać nazwy:

#showtooltip heart strike
/stopcasting
/startattack
/cast [harm,nodead]heart strike
/cast [harm,nodead]!rune strike
/run UIErrorsFrame:Hide()
Umiejętności które nie operują na global cooldownie(np Rune Strike) można łączyć z innymi

#showtooltip
/stopcasting
/cast vampiric blood
/cast blood tap
/cast vampiric blood
/cast rune tap
/use super Healing Potion
/use fel healthstone
Jeśli nie mamy run na vampiric blood, blood tap taką generuje a następnie drugi raz użyty Vampiric Blood już na pewno zadziała.
Wystarczy jeden klik. Spróbujcie tego samego dla swoich umiejętności generujących zasoby typu runic power, energii czy rage.

#showtooltip
/stopcasting
/startattack
/cast dancing rune weapon
/use [spec:2]13
Odpałka + trinket(w offspecu). Podobnie jak rune strike wyżej, trinket nie używa global cooldown. Nie można użyć jednocześnie dwóch trinketów lub trinketu i rękawic(inżynier).

#showtooltip 8
/cast [noflyable,nocombat] Charger; [nocombat] flying machine; 8
Nie można tu latać? No to koń. W przeciwnym wypadku latanie. Podczas walki użyje nitra w butach(inżynier). Zwróćcie uwagę na
strukturę: jeśli pierwszy warunek nie jest spełniony, macro przechodzi do sprawdzenia następnego poprzedzonego znakiem ";".
Ponieważ w dwóch pierwszych jest [nocombat] nie ma potrzeby przy trzecim pisać [combat].

#showtooltip
/stopcasting
/castsequence reset=360 army of the dead, death pact
Niektóre umiejętności jak Death Pact mogą zostać użyte tylko po Army of the dead lub Raise Dead więc logiczne jest wpisanie ich w castsequence. Przy #showtooltip najlepiej nie wpisywać nic - wyświetlana będzie pierwsza umiejętność a po użyciu jej - druga.

#showtooltip hand of salvation
/stopcasting
/cast [@mouseover,help,nodead] hand of salvation; [@player] hand of salvation
Macro w pierwszej kolejności sprawdza czy na kursorze (@mouseover) znajduje się kolega (help) i żyje (nodead). Jeżeli choć jeden z tych warunków nie jest spełniony macro przejdzie do sprawdzenia następnych warunków po znaku ";"

#showtooltip avenging wrath
/stopcasting
/cancelaura divine plea
/cast divine illumination
/cast divine favor
/use 13
/cast avenging wrath
/cast aura mastery
/cast [@mouseover,help,nodead] holy shock; holy shock
Macro typu burst. Cancelaura dla wyłączenia debuffa -50% leczenia. W przypadku wielu umiejętności w macro warto przy #showtooltip
dopisać jaki cooldown chcemy konkretnie śledzić - w tym przypadku jest to avenging wrath. Pozostawione puste wyświetli umiejętność/przedmiot znajdujący się na początku macro(divine illumination).

#showtooltip righteous defense
/stopcasting
/startattack
/assist [@mouseover,harm,nodead]
/cast [help] Righteous defense
/targetlasttarget [help]
Używa umiejętności na cel wroga nie zmieniając twojego. Można odwrócić logikę zmieniając help na harm a harm na help - wtedy użyjemy umiejętności na cel kolegi.

Zapraszam do dzielenia się swoimi pomysłami, a w razie pytań - pytać.

Edited by Rafadin
  • Like it! 1

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

×
×
  • Create New...